; --------------------------------

;

; "Nether Earth" by Argus Press Software

; Disassembled by Santiago Ontañón in 2022

; 

; --------------------------------

;

; Notes:

;

; - All the symbol names and comments in this file are my own interpretation of the original source 

;   code, they could be wrong. So, take them all with a grain of salt! And if you see any errors, 

;   please report!

;

; - Game binary disassembled using MDL: https://github.com/santiontanon/mdlz80optimizer

;

; - I decided to prefix each label by their address, e.g. "La600_start" instead of just "start" as, 

;   often, the code makes assumptions about these addresses. For example, when it checks if the 

;   most-significant byte of a pointer if #dc or #fd to know we are out of bounds of a map. By 

;   making the map label "Ldd00_map", it is at least clear that checking for "#dc" is to see if the 

;   pointer is lower than #dd00, which is the beginning of the map.

;

; - There is some unreachable code (see label Lae29) in the code base, that contains code that is 

;   probably left-over code.

; 

; - There are also two gaps in the zone of RAM designated for variables. So, probably some 

;   variables were defined, but unused in the final version of the code (search for "unused bytes" 

;   in this file).

; 

; - The music system is very interesting for a 48K Spectrum model:

;     - Look at "Lc4a7_title_music_loop"

;     - Basically, when playing music, the game runs a constant loop that iterates over 3 

;       oscillators that produce sound.

;     - These oscillators are just 3 loops in the code that make the speaker vibrate with some 

;       fixed frequencies.

;     - The interrupt routine has a script that, using self-modifiable code, modifies the

;       oscillator parameters in the loop.

;     - So, basically, the loop acts as a sound chip, and the interrupt basically sets its 

;       parameters, mimicking 3 channel sound.

;     - Since it's a dedicated loop, nothing can run in parallel with it. So, as soon as the player 

;       presses any key, music stops.

;

; - SFX:

;     - The game reads from the addresses in the Spectrum ROM and uses them to produce sound. This 

;       is probably just some random sound (as those values are not a wave, but assembler code), 

;       but the programmers chose different parts of the ROM that produce slightly different 

;       sounds when reproduced, which is pretty smart.

;

; - Game-play details, not fully documented in the instructions:

;     - Weapons all fly at the same altitude (10) regardless of the height of the robot.

;     - Electronics:

;         - increase the range of weapons by 1 tile (what the manual states being 3 miles).

;         - they also increase the distance robots can "see" an opponent from 10 to 12 tiles.

;     - Each player can have at most 24 robots.

;     - There can only be 5 bullets at a time in the whole game:

;         - one bullet for the player controlled robot

;         - two bullets fired by friendly robots

;         - two bullets fired by enemy robots

;     - How much damage weapons deal is quite curious:

;         - The game calculates (60 - (robot height + ground height))/4 as the "base damage".

;         - Then cannon deals 2x the base damage, missiles 3x, and phasers 4x. (the Spanish 

;           instruction manual is wrong here, stating that missiles do the same damage as cannon, 

;           English is correct).

;         - So, robots that are on high ground receive less damage! Stand on a mountain to make a 

;           robot more resistant!

;     - Since a robot can have at most 3 weapons, we have (see the 

;       Ld7b4_piece_heights data below):

;         - The maximum height of a robot is: 11 + 6 + 7 + 7 + 7 = 38 (bipod, missiles, phase, 

;           nuclear, electronics). This is the most resistant robot!

;         - The minimum height of a robot is: 7 + 6 = 13 (tracks, cannon). This is the weakest 

;           robot!

;     - So, for example: phasers against the weakest robot (at ground level) deal: ((60 - 13)/4)*4 

;       = 44 damage.

;     - The robot/enemy AI is extremely simple:

;         - see "Lb154_robot_ai_update" for the code that implements the AI of the robots, 

;           including their limited "path-finding", and targetting.

;         - see "Lb7f4_update_enemy_ai" for the code that implements the strategy of the enemy 

;           player.

; 

; - Terminology:

;     - I often use the abbreviation "ptr." for "pointer".

;     - I often use the term "one-hot" (vector/byte). This is a way to represent numbers, where 

;       only one bit of the byte is set to 1, and the others are zero. The number encoded is the

;       index of the bit that is set to 1. For example:

;         - 1 encoded as a one-hot vector is: 00000001

;         - 2 encoded as a one-hot vector is: 00000010

;         - 3 encoded as a one-hot vector is: 00000100

;         - 4 encoded as a one-hot vector is: 00001000

;         - etc.

;

; --------------------------------

; --------------------------------

; BIOS Functions and constants:

; - Information obtained from:

;   https://worldofspectrum.net/pub/sinclair/books/s/SpectrumMachineCodeReferenceGuideThe.pdf

L0205_BIOS_KEYCODE_TABLE: equ #0205

L028e_BIOS_POLL_KEYBOARD: equ #028e  ; Polls keyboard and builds up key code in DE

L0556_BIOS_READ_FROM_TAPE: equ #0556  ; Load if carry set, load tape header if A=0 (nz=data). 

                                      ; IX=address, DE=byte count

L0562_BIOS_READ_FROM_TAPE_SKIP_TESTS: equ #0562

L04c2_BIOS_CASSETTE_SAVE: equ #04c2

L04d0_BIOS_CASSETTE_SAVE_SKIP_TESTS: equ #04d0

L4000_VIDEOMEM_PATTERNS: equ #4000

L5800_VIDEOMEM_ATTRIBUTES: equ #5800

ULA_PORT: equ #fe

KEMPSTON_JOYSTICK_PORT: equ 31

INTERFACE2_JOYSTICK_PORT_MSB: equ #ef

COLOR_BRIGHT: equ #40

COLOR_BLACK: equ 0

COLOR_BLUE: equ 1

COLOR_RED: equ 2

COLOR_PINK: equ 3

COLOR_GREEN: equ 4

COLOR_CYAN: equ 5

COLOR_YELLOW: equ 6

COLOR_WHITE: equ 7

PAPER_COLOR_MULTIPLIER: equ 8

; --------------------------------

; Commands recognized by Ld42d_execute_ui_script:

CMD_END: equ 0

CMD_SET_POSITION: equ 1

CMD_SET_ATTRIBUTE: equ 2

CMD_NEXT_LINE: equ 3

CMD_SET_SCALE: equ 4

; --------------------------------

INPUT_KEYBOARD: equ 1

INPUT_KEMPSTON: equ 2

INPUT_INTERFACE2: equ 3

; --------------------------------

; Game constants:

INITIAL_PLAYER_RESOURCES: equ 20

MAX_ROBOTS_PER_PLAYER: equ 24

MAX_BULLETS: equ 5

N_WARBASES: equ 4

N_FACTORIES: equ 24

BUILDING_CAPTURE_TIME: equ 144

MIN_INTERRUPTS_PER_GAME_CYCLE: equ 10  ; game maximum speed is 5 frames per second.

MAX_PLAYER_ALTITUDE: equ 48

MIN_PLAYER_X: equ 14

MAX_PLAYER_X: equ 501

MAP_LENGTH: equ 512  ; x coordinate

MAP_WIDTH: equ 16  ; y coordinate

ROBOT_ORDERS_STOP_AND_DEFEND: equ 0

ROBOT_ORDERS_ADVANCE: equ 1

ROBOT_ORDERS_RETREAT: equ 2

ROBOT_ORDERS_DESTROY_ENEMY_ROBOTS: equ 3

ROBOT_ORDERS_DESTROY_ENEMY_FACTORIES: equ 4

ROBOT_ORDERS_DESTROY_ENEMY_WARBASES: equ 5

ROBOT_ORDERS_CAPTURE_NEUTRAL_FACTORIES: equ 6

ROBOT_ORDERS_CAPTURE_ENEMY_FACTORIES: equ 7

ROBOT_ORDERS_CAPTURE_ENEMY_WARBASES: equ 8

ROBOT_CONTROL_AUTO: equ 0

ROBOT_CONTROL_PLAYER_LANDED: equ 1

ROBOT_CONTROL_DIRECT_CONTROL: equ 2

ROBOT_CONTROL_ENEMY_AI: equ 128

WEAPON_RANGE_DEFAULT: equ 5

WEAPON_RANGE_MISSILES: equ 7

; --------------------------------

; Game structs:

ROBOT_STRUCT_SIZE: equ 16

ROBOT_STRUCT_MAP_PTR: equ 0  ; 2 bytes (the first byte set to 0 when there is no robot in this 

                             ; struct).

ROBOT_STRUCT_X: equ 2  ; 2 bytes

ROBOT_STRUCT_Y: equ 4

ROBOT_STRUCT_DESIRED_MOVE_DIRECTION: equ 5

ROBOT_STRUCT_NUMBER_OF_STEPS_TO_KEEP_WALKING: equ 6

ROBOT_STRUCT_PIECES: equ 7

ROBOT_STRUCT_DIRECTION: equ 8  ; one-hot representation: #01, #02, #04, #08

ROBOT_STRUCT_HEIGHT: equ 9

ROBOT_STRUCT_CONTROL: equ 10

ROBOT_STRUCT_ORDERS: equ 11

ROBOT_STRUCT_STRENGTH: equ 12

ROBOT_STRUCT_ALTITUDE: equ 13

ROBOT_STRUCT_ORDERS_ARGUMENT: equ 14  ; This can be # of miles, target robot index, etc.

ROBOT_STRICT_CYCLES_TO_NEXT_UPDATE: equ 15

BULLET_STRUCT_SIZE: equ 9

BULLET_STRUCT_MAP_PTR: equ 0  ; 2 bytes (the first byte set to 0 when there is no bullet in this 

                              ; struct).

BULLET_STRUCT_X: equ 2  ; 2 bytes

BULLET_STRUCT_Y: equ 4

BULLET_STRUCT_DIRECTION: equ 5

BULLET_STRUCT_RANGE: equ 6

BULLET_STRUCT_TYPE: equ 7  ; 1: cannon, 2: missiles, 3: phasers

BULLET_STRUCT_ALTITUDE: equ 8

BUILDING_STRUCT_SIZE: equ 5

BUILDING_STRUCT_X: equ 0  ; 2 bytes

BUILDING_STRUCT_Y: equ 2

BUILDING_STRUCT_TYPE: equ 3  ; contains type + owner (owner in the most-significant bits: bit 6 

                             ; player 1, bit 5 player 2). bit 7 indicates building is destroyed.

BUILDING_STRUCT_TIMER: equ 4  ; this counts the time the building is occupied by a robot

BUILDING_DECORATION_STRUCT_SIZE: equ 3

BUILDING_DECORATION_STRUCT_MAP_PTR: equ 0

BUILDING_DECORATION_STRUCT_TYPE: equ 2

; --------------------------------

; RAM variables/buffers in the low region of RAM:

; The first 3200 bytes (starting at #5b00) are used as a double buffer, to render

; the screen there, before it is copied over to the video memory. 3200 bytes, as

; the game area is 160x160 pixels wide. So, 160/8 = 20 bytes per line, and 20*160 = 3200.

L5b00: equ #5b00

L5b00_double_buffer: equ #5b00

; --------------------------------

; Game graphic data"

    org #6780

    include "netherearth-annotated-data.asm"

    ds #a600 - $, 0  ; 150 bytes of empty space until the game code starts.

; --------------------------------

; Game entry point    

La600_start:

    ; Set up the interrupts:

f3 

    di

31 00 00 

        ld sp, 0

21 00 fe 

        ld hl, Lfe00_interrupt_vector_table

01 fd 00 

        ld bc, #00fd

        ; Write #fd to the interrupt vector table 257 times

La60a_interrupt_vector_table_init_loop:

71 

        ld (hl), c

23 

        inc hl

10 fc 

        djnz La60a_interrupt_vector_table_init_loop

71 

        ld (hl), c

3e c3 

        ld a, #c3  ; jp opcode

32 fd fd 

        ld (Lfdfd_interrupt_jp), a

21 9c d5 

        ld hl, Ld59c_empty_interrupt

22 fe fd 

        ld (Lfdfe_interrupt_pointer), hl  ; sets the interrupt routine

3e fe 

        ld a, #fe

ed 47 

        ld i, a  ; sets the interrupt vector tp #fe00

ed 5e 

        im 2

fb 

    ei

    ; Initialize the random number generator:

21 39 30 

    ld hl, 12345  ; random seed

22 00 fd 

    ld (Lfd00_random_seed), hl

22 02 fd 

    ld (Lfd00_random_seed + 2), hl

cd 00 c1 

    call Lc100_title_screen

20 5f 

    jr nz, La68e_game_loop_start  ; Start from a saved game

    ; Start new game from scratch:

    ; Clear memory buffers:

21 00 da 

    ld hl, Lda00_player1_robots

11 01 da 

    ld de, Lda00_player1_robots + 1

01 ff 02 

    ld bc, 2 * MAX_ROBOTS_PER_PLAYER * ROBOT_STRUCT_SIZE - 1

36 00 

    ld (hl), 0

ed b0 

    ldir

21 04 fd 

    ld hl, Lfd04_script_video_pattern_ptr

11 05 fd 

    ld de, Lfd04_script_video_pattern_ptr + 1

01 f8 00 

    ld bc, 248

36 00 

    ld (hl), 0

ed b0 

    ldir  ; This clears a whole set of in-game variables starting at Lfd04_script_video_pattern_ptr

21 01 ff 

    ld hl, Lff01_building_decorations

11 02 ff 

    ld de, Lff01_building_decorations + 1

01 c8 00 

    ld bc, 200  ; Potential optimization: change to 167 since only 168 bytes need to be cleared 

                ; here.

36 00 

    ld (hl), 0

ed b0 

    ldir

21 d3 d7 

    ld hl, Ld7d3_bullets

11 d4 d7 

    ld de, Ld7d3_bullets + 1

01 2c 00 

    ld bc, MAX_BULLETS * BULLET_STRUCT_SIZE - 1

36 00 

    ld (hl), 0

ed b0 

    ldir

    ; Initialize variables:

21 00 dd 

    ld hl, Ldd00_map

22 06 fd 

    ld (Lfd06_scroll_ptr), hl

21 00 00 

    ld hl, 0

22 0a fd 

    ld (Lfd0a_scroll_x), hl

21 11 00 

    ld hl, 17

22 0e fd 

    ld (Lfd0e_player_x), hl  ; set player start x

3e 0a 

    ld a, 10

32 0d fd 

    ld (Lfd0d_player_y), a  ; set player start y

af 

    xor a

32 10 fd 

    ld (Lfd10_player_altitude), a  ; set player start altitude

3e 03 

    ld a, 3

32 30 fd 

    ld (Lfd30_player_elevate_timer), a  ; make the player float a bit right at game start

3e 14 

    ld a, INITIAL_PLAYER_RESOURCES

32 22 fd 

    ld (Lfd22_player1_resource_counts), a

32 4a fd 

    ld (Lfd4a_player2_resource_counts), a

cd 6f bc 

    call Lbc6f_initialize_map

; --------------------------------

; This is the main game loop:

La68e_game_loop_start:

cd d7 cf 

    call Lcfd7_draw_blank_map_in_buffer

cd ca d0 

    call Ld0ca_draw_in_game_screen_and_hud

21 66 d5 

    ld hl, Ld566_interrupt

22 fe fd 

    ld (Lfdfe_interrupt_pointer), hl

La69a_game_loop:

cd 7c d3 

    call Ld37c_read_keyboard_joystick_input

cd 11 af 

    call Laf11_player_ship_keyboard_control

cd ca b0 

    call Lb0ca_update_robots_bullets_and_ai

cd bd cc 

    call Lccbd_redraw_game_area

cd 62 ad 

    call Lad62_increase_time

cd a0 cc 

    call Lcca0_compute_player_map_ptr

cb 76 

    bit 6, (hl)

28 5d 

    jr z, La70d_game_loop_continue

cd d8 cd 

    call Lcdd8_get_robot_at_ptr

20 13 

    jr nz, La6c8_not_landed_on_a_robot

78 

    ld a, b

fe 19 

    cp MAX_ROBOTS_PER_PLAYER + 1  ; if it's not one of the player's robots, ignore

38 53 

    jr c, La70d_game_loop_continue

3a 10 fd 

    ld a, (Lfd10_player_altitude)

fd 96 09 

    sub (iy + ROBOT_STRUCT_HEIGHT)

fd 96 0d 

    sub (iy + ROBOT_STRUCT_ALTITUDE)

cc 20 a7 

    call z, La720_land_on_robot  ; if we are right on top of the robot, control it!

18 45 

    jr La70d_game_loop_continue

La6c8_not_landed_on_a_robot:

cd f5 cd 

    call Lcdf5_find_building_decoration_with_ptr

20 40 

    jr nz, La70d_game_loop_continue  ; player is not on top of any ownable building

fd 7e 02 

    ld a, (iy + BUILDING_DECORATION_STRUCT_TYPE)

b7 

    or a

20 3a 

    jr nz, La70d_game_loop_continue  ; player is not on top of an "H" decoration

3a 10 fd 

    ld a, (Lfd10_player_altitude)

fe 0f 

    cp 15

20 33 

    jr nz, La70d_game_loop_continue  ; player is not at the right height

fd 6e 00 

    ld l, (iy + BUILDING_DECORATION_STRUCT_MAP_PTR)

fd 7e 01 

    ld a, (iy + BUILDING_DECORATION_STRUCT_MAP_PTR + 1)

c6 08 

    add a, 8

67 

    ld h, a

    ; check for bit 6 in a 2x2 rectangle around the building map ptr, this is to

    ; make sure the building is still there and not destroyed:

7e 

    ld a, (hl)

24 

    inc h

24 

    inc h

b6 

    or (hl)

2b 

    dec hl

b6 

    or (hl)

23 

    inc hl

23 

    inc hl

b6 

    or (hl)

e6 40 

    and #40

20 1d 

    jr nz, La70d_game_loop_continue  ; not landed on a warbase

cd 49 c8 

    call Lc849_robot_construction_if_possible

    ; Reset state of newly created robot:

fd 36 05 04 

    ld (iy + ROBOT_STRUCT_DESIRED_MOVE_DIRECTION), 4  ; more down by default

fd 36 06 05 

    ld (iy + ROBOT_STRUCT_NUMBER_OF_STEPS_TO_KEEP_WALKING), 5  ; walk 5 steps after exiting the 

                                                               ; base, and stop

fd 36 0b 00 

    ld (iy + ROBOT_STRUCT_ORDERS), ROBOT_ORDERS_STOP_AND_DEFEND

fd 36 0c 64 

    ld (iy + ROBOT_STRUCT_STRENGTH), 100

fd 36 0f 01 

    ld (iy + ROBOT_STRICT_CYCLES_TO_NEXT_UPDATE), 1

cd 40 bb 

    call Lbb40_count_robots

cd 93 d2 

    call Ld293_update_stats_in_right_hud

La70d_game_loop_continue:

3a 0c fd 

    ld a, (Lfd0c_keyboard_state)

cb 77 

    bit 6, a  ; restart key

c2 00 a6 

    jp nz, La600_start

cb 6f 

    bit 5, a  ; save game key

ca 9a a6 

    jp z, La69a_game_loop

cd 8d c2 

    call Lc28d_save_game

c3 8e a6 

    jp La68e_game_loop_start

; --------------------------------

; Player lands on a robot.

; Input:

; - iy: robot player landed on

La720_land_on_robot:

fd e5 

    push iy

dd e1 

    pop ix

dd 36 0a 01 

    ld (ix + ROBOT_STRUCT_CONTROL), ROBOT_CONTROL_PLAYER_LANDED

3e 04 

    ld a, 4

32 1f fd 

    ld (Lfd1f_cursor_position), a

3e 01 

    ld a, 1

32 39 fd 

    ld (Lfd39_current_in_game_right_hud), a

La732_land_on_robot_internal:

cd f6 d2 

    call Ld2f6_clear_in_game_right_hud

cd 2d d4 

    call Ld42d_execute_ui_script

    ; script start:

        db CMD_SET_POSITION, #04, #17

        db CMD_SET_ATTRIBUTE, #4d

        db "DIRECT  "

        db CMD_NEXT_LINE

        db " CONTROL"

        db CMD_NEXT_LINE

        db CMD_NEXT_LINE

        db "GIVE    "

        db CMD_NEXT_LINE

        db "  ORDERS"

        db CMD_NEXT_LINE

        db CMD_NEXT_LINE

        db "COMBAT  "

        db CMD_NEXT_LINE

        db "    MODE"

        db CMD_NEXT_LINE

        db CMD_NEXT_LINE

        db "LEAVE   "

        db CMD_NEXT_LINE

        db "   ROBOT"

        db CMD_SET_POSITION, #11, #17

        db CMD_SET_ATTRIBUTE, #46

        db "-ORDERS-"

        db CMD_END

    ; script end:

    ; Print the robot current orders in the hud:

dd 46 0b 

    ld b, (ix + ROBOT_STRUCT_ORDERS)

04 

    inc b

21 2d a8 

    ld hl, La848_possible_robot_order_names - 27

11 1b 00 

    ld de, 27

La79f_get_orders_name_loop:

19 

    add hl, de

10 fd 

    djnz La79f_get_orders_name_loop

    ; Copy the current orders to the script below, so we can draw it:

11 b2 a7 

    ld de, La7b2_current_orders_buffer

01 1b 00 

    ld bc, 27

ed b0 

    ldir

cd 2d d4 

    call Ld42d_execute_ui_script

    ; script start:

        db CMD_SET_POSITION, #12, #17

        db CMD_SET_ATTRIBUTE, #45

La7b2_current_orders_buffer:

        db #00, #00, #00, #00, #00, #00, #00, #00, #00, #00, #00, #00, #00, #00, #00, #00

        db #00, #00, #00, #00, #00, #00, #00, #00, #00, #00, #00

    ; script end:

dd 7e 0b 

    ld a, (ix + ROBOT_STRUCT_ORDERS)

3d 

    dec a

fe 02 

    cp 2

30 0f 

    jr nc, La7e4_no_miles

    ; If there orders are advance/retreat, display the # of miles:

cd 2d d4 

    call Ld42d_execute_ui_script

    ; script start:

        db CMD_SET_POSITION, #13, #19

        db CMD_END

    ; script end:

dd 7e 0e 

    ld a, (ix + ROBOT_STRUCT_ORDERS_ARGUMENT)

cb 3f 

    srl a

cd e5 d3 

    call Ld3e5_render_8bit_number

La7e4_no_miles:

cd 1d a8 

    call La81d_draw_robot_strength

21 37 58 

    ld hl, L5800_VIDEOMEM_ATTRIBUTES + #0037

1e 05 

    ld e, 5

3a 1f fd 

    ld a, (Lfd1f_cursor_position)

cd d7 ac 

    call Lacd7_right_hud_menu_control

32 1f fd 

    ld (Lfd1f_cursor_position), a

3d 

    dec a

ca 3b a9 

    jp z, La93b_direct_control

3d 

    dec a

ca 71 a9 

    jp z, La971_give_orders

3d 

    dec a

ca 00 ac 

    jp z, Lac00_combat_mode

3e 78 

    ld a, 120

cd ac cc 

    call Lccac_beep

af 

    xor a

dd 77 06 

    ld (ix + ROBOT_STRUCT_NUMBER_OF_STEPS_TO_KEEP_WALKING), a

dd 77 0a 

    ld (ix + ROBOT_STRUCT_CONTROL), a  ; robot controls itself again

3e 05 

    ld a, 5

32 30 fd 

    ld (Lfd30_player_elevate_timer), a  ; make the player float a bit after exiting a robot

La812_exit_robot:

cd f6 d2 

    call Ld2f6_clear_in_game_right_hud  ; potential optimization: this line is not needed

af 

    xor a

32 39 fd 

    ld (Lfd39_current_in_game_right_hud), a

cd e5 d1 

    call Ld1e5_draw_in_game_right_hud  ; potential optimization: tail recursion

c9 

    ret

; --------------------------------

; Draws the remaining strength (hit points) of a robot.

La81d_draw_robot_strength:

cd 2d d4 

    call Ld42d_execute_ui_script

    ; script start:

        db CMD_SET_POSITION, #16, #17

        db CMD_SET_ATTRIBUTE, #46

        db "STRENGTH"

        db CMD_SET_POSITION, #17, #19

        db CMD_SET_ATTRIBUTE, #47

        db CMD_END

    ; script end:

dd 7e 0c 

    ld a, (ix + ROBOT_STRUCT_STRENGTH)

b7 

    or a

f2 3b a8 

    jp p, La83b_positive_strength

af 

    xor a

La83b_positive_strength:

6f 

    ld l, a

26 00 

    ld h, 0

1e 20 

    ld e, " "

cd 01 d4 

    call Ld401_render_16bit_number_3digits

3e 25 

    ld a, "%"

c3 27 d4 

    jp Ld427_draw_character_saving_registers

; --------------------------------

La848_possible_robot_order_names:

    db "  STOP  "

    db CMD_NEXT_LINE

    db "  AND   "

    db CMD_NEXT_LINE

    db " DEFEND "

    db CMD_END

    db "ADVANCE "

    db CMD_NEXT_LINE

    db "        "

    db CMD_NEXT_LINE

    db " MILES  "

    db CMD_END

    db "RETREAT "

    db CMD_NEXT_LINE

    db "        "

    db CMD_NEXT_LINE

    db " MILES  "

    db CMD_END

    db "DESTROY "

    db CMD_NEXT_LINE

    db " ENEMY  "

    db CMD_NEXT_LINE

    db " ROBOTS "

    db CMD_END

    db "DESTROY "

    db CMD_NEXT_LINE

    db " ENEMY  "

    db CMD_NEXT_LINE

    db "FACTORYS"

    db CMD_END

    db "DESTROY "

    db CMD_NEXT_LINE

    db " ENEMY  "

    db CMD_NEXT_LINE

    db "WARBASES"

    db CMD_END

    db "CAPTURE "

    db CMD_NEXT_LINE

    db "NEUTRAL "

    db CMD_NEXT_LINE

    db "FACTORYS"

    db CMD_END

    db "CAPTURE "

    db CMD_NEXT_LINE

    db " ENEMY  "

    db CMD_NEXT_LINE

    db "FACTORYS"

    db CMD_END

    db "CAPTURE "

    db CMD_NEXT_LINE

    db " ENEMY  "

    db CMD_NEXT_LINE

    db "WARBASES"

    db CMD_END

; --------------------------------

; Jumps to the direct-control interface, and goes back to the "land on robot" menu after that.

La93b_direct_control:

cd 41 a9 

    call La941_direct_control_internal

c3 32 a7 

    jp La732_land_on_robot_internal

; --------------------------------

; Direct control of a robot.

La941_direct_control_internal:

dd 36 0a 02 

    ld (ix + ROBOT_STRUCT_CONTROL), ROBOT_CONTROL_DIRECT_CONTROL

dd 36 05 00 

    ld (ix + ROBOT_STRUCT_DESIRED_MOVE_DIRECTION), 0  ; stop the automatic movement of the robot

cd 57 ad 

    call Lad57_wait_until_no_keys_pressed

La94c_direct_control_loop:

cd ca b0 

    call Lb0ca_update_robots_bullets_and_ai

cd bd cc 

    call Lccbd_redraw_game_area

cd 48 b0 

    call Lb048_update_radar

cd 62 ad 

    call Lad62_increase_time

cd 1d a8 

    call La81d_draw_robot_strength

dd 7e 01 

    ld a, (ix + 1)

b7 

    or a

c8 

    ret z  ; If the robot is destroyed, exit.

cd 7c d3 

    call Ld37c_read_keyboard_joystick_input

e6 10 

    and 16  ; If we press "fire", exit

28 e5 

    jr z, La94c_direct_control_loop

dd 36 0a 01 

    ld (ix + ROBOT_STRUCT_CONTROL), ROBOT_CONTROL_PLAYER_LANDED

3e 78 

    ld a, 120

cd ac cc 

    call Lccac_beep

c9 

    ret

; --------------------------------

; This function implements the menu to give new orders to a robot.

La971_give_orders:

cd f6 d2 

    call Ld2f6_clear_in_game_right_hud

cd 2d d4 

    call Ld42d_execute_ui_script

    ; script start:

        db CMD_SET_POSITION, #04, #18

        db CMD_SET_ATTRIBUTE, #47

        db "SELECT"

        db CMD_NEXT_LINE

        db "ORDERS"

        db CMD_SET_ATTRIBUTE, #4d

        db CMD_SET_POSITION, #07, #17

        db "STOP AND"

        db CMD_NEXT_LINE

        db "  DEFEND"

        db CMD_NEXT_LINE

        db CMD_NEXT_LINE

        db "ADVANCE "

        db CMD_NEXT_LINE

        db "?? MILES"

        db CMD_NEXT_LINE

        db CMD_NEXT_LINE

        db "RETREAT "

        db CMD_NEXT_LINE

        db "?? MILES"

        db CMD_NEXT_LINE

        db CMD_NEXT_LINE

        db "SEARCH &"

        db CMD_NEXT_LINE

        db " DESTROY"

        db CMD_NEXT_LINE

        db CMD_NEXT_LINE

        db "SEARCH &"

        db CMD_NEXT_LINE

        db " CAPTURE"

        db CMD_END

    ; script end:

cd 1d a8 

    call La81d_draw_robot_strength

21 97 58 

    ld hl, L5800_VIDEOMEM_ATTRIBUTES + #0097  ; ptr to the start of the menu attributes

1e 06 

    ld e, 6  ; this menu has 5 options

3e 01 

    ld a, 1  ; we start in option 1

cd d7 ac 

    call Lacd7_right_hud_menu_control

f5 

    push af

cd 57 ad 

        call Lad57_wait_until_no_keys_pressed

f1 

    pop af

3d 

    dec a

20 0b 

    jr nz, Laa0c_no_stop_and_defend

dd 77 0b 

    ld (ix + ROBOT_STRUCT_ORDERS), a  ; stop and defend

3e 78 

    ld a, 120

cd ac cc 

    call Lccac_beep

c3 32 a7 

    jp La732_land_on_robot_internal

Laa0c_no_stop_and_defend:

fe 03 

    cp 3

d2 cf aa 

    jp nc, Laacf_give_capture_or_destroy_orders

    ; We have selected advance or retreat:

dd 77 0b 

    ld (ix + ROBOT_STRUCT_ORDERS), a

f5 

    push af

cd f6 d2 

        call Ld2f6_clear_in_game_right_hud

f1 

    pop af

3d 

    dec a

20 13 

    jr nz, Laa2f_retreat

cd 2d d4 

    call Ld42d_execute_ui_script

    ; Script start:

        db CMD_SET_POSITION, #05, #17

        db CMD_SET_ATTRIBUTE, #4f

        db "ADVANCE "

        db CMD_END

    ; Script end:

18 11 

    jr Laa40_advance_or_retreat_drawn

Laa2f_retreat:

cd 2d d4 

    call Ld42d_execute_ui_script

    ; Script start:

        db CMD_SET_POSITION, #05, #17

        db CMD_SET_ATTRIBUTE, #4f

        db "RETREAT "

        db CMD_END

    ; Script end:

Laa40_advance_or_retreat_drawn:

cd 2d d4 

    call Ld42d_execute_ui_script

    ; Script start:

        db CMD_NEXT_LINE

        db "?? MILES"

        db CMD_SET_POSITION, #09, #17

        db CMD_SET_ATTRIBUTE, #45

        db " SELECT"

        db CMD_NEXT_LINE

        db "DISTANCE"

        db CMD_SET_POSITION, #0d, #18

        db CMD_SET_ATTRIBUTE, #46

        db "0 MILES"

        db CMD_END

    ; Script end:

16 00 

    ld d, 0  ; 0 miles to start

Laa70_select_miles_loop:

d5 

    push de

cd 1d a8 

        call La81d_draw_robot_strength

cd ca b0 

        call Lb0ca_update_robots_bullets_and_ai

cd bd cc 

        call Lccbd_redraw_game_area

cd 48 b0 

        call Lb048_update_radar

cd 62 ad 

        call Lad62_increase_time

d1 

    pop de

dd 7e 01 

    ld a, (ix + 1)

b7 

    or a  ; If robot is destroyed, exit.

ca 12 a8 

    jp z, La812_exit_robot

cd 7c d3 

    call Ld37c_read_keyboard_joystick_input

cb 67 

    bit 4, a

20 29 

    jr nz, Laab8_miles_selected  ; If fire pressed

4a 

    ld c, d

0f 

    rrca

0f 

    rrca

e6 03 

    and 3

28 da 

    jr z, Laa70_select_miles_loop  ; if we have not pressed up/down

e6 02 

    and 2

47 

    ld b, a

87 

    add a, a

87 

    add a, a

80 

    add a, b

d6 05 

    sub 5  ; If we have pressed up, a = 5, otherwise, a = -5

81 

    add a, c  ; c was storing the # of miles

fe 33 

    cp 51

30 cd 

    jr nc, Laa70_select_miles_loop  ; Limit miles to 50

57 

    ld d, a  ; update the # miles

cd 2d d4 

    call Ld42d_execute_ui_script

    ; Script start:

        db CMD_SET_POSITION, #0d, #17

        db CMD_SET_ATTRIBUTE, #46

        db CMD_END

    ; Script end

7a 

    ld a, d

cd e5 d3 

    call Ld3e5_render_8bit_number

3e 14 

    ld a, 20

cd ac cc 

    call Lccac_beep

18 b8 

    jr Laa70_select_miles_loop

Laab8_miles_selected:

7a 

    ld a, d

07 

    rlca  ; multiply by 2: 1 mile == 2 coordinate units

dd 77 0e 

    ld (ix + ROBOT_STRUCT_ORDERS_ARGUMENT), a  ; set the number of miles to advance

b7 

    or a

20 04 

    jr nz, Laac4  ; "advance/retreat 0 miles" is equivalent to stop and defend.

dd 36 0b 00 

    ld (ix + ROBOT_STRUCT_ORDERS), ROBOT_ORDERS_STOP_AND_DEFEND

Laac4:

3e 78 

    ld a, 120

cd ac cc 

    call Lccac_beep

cd 57 ad 

    call Lad57_wait_until_no_keys_pressed

c3 32 a7 

    jp La732_land_on_robot_internal

Laacf_give_capture_or_destroy_orders:

c2 4e ab 

    jp nz, Lab4e_give_capture_orders

    ; Destroy:

cd f6 d2 

    call Ld2f6_clear_in_game_right_hud

cd 2d d4 

    call Ld42d_execute_ui_script

    ; Script start:

        db CMD_SET_POSITION, #04, #17

        db CMD_SET_ATTRIBUTE, #4f

        db "SEARCH &"

        db CMD_NEXT_LINE

        db " DESTROY"

        db CMD_SET_POSITION, #08, #18

        db CMD_SET_ATTRIBUTE, #45

        db "SELECT"

        db CMD_NEXT_LINE

        db "TARGET"

        db CMD_SET_POSITION, #0c, #17